Community
Modules 24

Control.Monad.Trans.State.Lazy

experimental

Lazy state monads, passing an updatable state through a computation. See below for examples.

Some computations may not require the full power of state transformers:

  • For a read-only state, see Control.Monad.Trans.Reader.

  • To accumulate a value without using it on the way, see Control.Monad.Trans.Writer.

In this version, sequencing of computations is lazy, so that for example the following produces a usable result:

evalState (sequence $ repeat $ do { n <- get; put (n*2); return n }) 1

For a strict version with the same interface, see Control.Monad.Trans.State.Strict.

The State monad

type State s = StateT s Identity

A state monad parameterized by the type s of the state to carry.

The return function leaves the state unchanged, while >>= uses the final state of the first computation as the initial state of the second.

state :: (Monad m) => (s -> (a, s)) -> StateT s m a

Construct a state monad computation from a function. (The inverse of runState.)

equivalent state-passing computation

(s -> (a, s))

pure state transformer

runState :: State s a -> s -> (a, s)

Unwrap a state monad computation as a function. (The inverse of state.)

state-passing computation to execute

s

initial state

(a, s)

return value and final state

evalState :: State s a -> s -> a

Evaluate a state computation with the given initial state and return the final value, discarding the final state.

  • evalState m s = fst (runState m s)

state-passing computation to execute

s

initial value

a

return value of the state computation

execState :: State s a -> s -> s

Evaluate a state computation with the given initial state and return the final state, discarding the final value.

  • execState m s = snd (runState m s)

state-passing computation to execute

s

initial value

s

final state

mapState :: ((a, s) -> (b, s)) -> State s a -> State s b

Map both the return value and final state of a computation using the given function.

  • runState (mapState f m) = f . runState m

withState :: (s -> s) -> State s a -> State s a

withState f m executes action m on a state modified by applying f.

  • withState f m = modify f >> m

The StateT monad transformer

newtype StateT s m a

A state transformer monad parameterized by:

  • s - The state.

  • m - The inner monad.

The return function leaves the state unchanged, while >>= uses the final state of the first computation as the initial state of the second.

StateT :: s -> m (a, s) -> StateT s m a

evalStateT :: (Monad m) => StateT s m a -> s -> m a

Evaluate a state computation with the given initial state and return the final value, discarding the final state.

  • evalStateT m s = liftM fst (runStateT m s)

execStateT :: (Monad m) => StateT s m a -> s -> m s

Evaluate a state computation with the given initial state and return the final state, discarding the final value.

  • execStateT m s = liftM snd (runStateT m s)

mapStateT :: (m (a, s) -> n (b, s)) -> StateT s m a -> StateT s n b

Map both the return value and final state of a computation using the given function.

  • runStateT (mapStateT f m) = f . runStateT m

withStateT :: (s -> s) -> StateT s m a -> StateT s m a

withStateT f m executes action m on a state modified by applying f.

  • withStateT f m = modify f >> m

State operations

get :: (Monad m) => StateT s m s

Fetch the current value of the state within the monad.

put :: (Monad m) => s -> StateT s m ()

put s sets the state within the monad to s.

modify :: (Monad m) => (s -> s) -> StateT s m ()

modify f is an action that updates the state to the result of applying f to the current state.

  • modify f = get >>= (put . f)

modify' :: (Monad m) => (s -> s) -> StateT s m ()

A variant of modify in which the computation is strict in the new state.

  • modify' f = get >>= (($!) put . f)

modifyM :: (Monad m) => (s -> m s) -> StateT s m ()

A variant of modify in which the new state is generated by a monadic action.

gets :: (Monad m) => (s -> a) -> StateT s m a

Get a specific component of the state, using a projection function supplied.

  • gets f = liftM f get

Lifting other operations

liftCallCC :: CallCC m (a, s) (b, s) -> CallCC (StateT s m) a b

Uniform lifting of a callCC operation to the new monad. This version rolls back to the original state on entering the continuation.

liftCallCC' :: CallCC m (a, s) (b, s) -> CallCC (StateT s m) a b

In-situ lifting of a callCC operation to the new monad. This version uses the current state on entering the continuation. It does not satisfy the uniformity property (see Control.Monad.Signatures).

liftCatch :: Catch e m (a, s) -> Catch e (StateT s m) a

Lift a catchE operation to the new monad. The uniformity property (see Control.Monad.Signatures) implies that the lifted catchE rolls back to the original state on entering the handler.

liftListen :: (Monad m) => Listen w m (a, s) -> Listen w (StateT s m) a

Lift a listen operation to the new monad.

liftPass :: (Monad m) => Pass w m (a, s) -> Pass w (StateT s m) a

Lift a pass operation to the new monad.

Conversion to and from the strict version

strictToLazyStateT :: Strict.StateT s m a -> StateT s m a

Convert from the strict version to the lazy version

lazyToStrictStateT :: StateT s m a -> Strict.StateT s m a

Convert from the lazy version to the strict version

Examples

** State monads

Parser from ParseLib with Hugs:

type Parser a = StateT String [] a
   ==> StateT (String -> [(a,String)])

For example, item can be written as:

item = do (x:xs) <- get
       put xs
       return x

type BoringState s a = StateT s Identity a
     ==> StateT (s -> Identity (a,s))

type StateWithIO s a = StateT s IO a
     ==> StateT (s -> IO (a,s))

type StateWithErr s a = StateT s Maybe a
     ==> StateT (s -> Maybe (a,s))

Counting

A function to increment a counter. Taken from the paper "Generalising Monads to Arrows", John Hughes (http://www.cse.chalmers.se/~rjmh/), November 1998:

tick :: State Int Int
tick = do n <- get
          put (n+1)
          return n

Add one to the given number using the state monad:

plusOne :: Int -> Int
plusOne n = execState tick n

A contrived addition example. Works only with positive numbers:

plus :: Int -> Int -> Int
plus n x = execState (sequence $ replicate n tick) x

Labelling trees

An example from The Craft of Functional Programming, Simon Thompson (http://www.cs.kent.ac.uk/people/staff/sjt/), Addison-Wesley 1999: "Given an arbitrary tree, transform it to a tree of integers in which the original elements are replaced by natural numbers, starting from 0. The same element has to be replaced by the same number at every occurrence, and when we meet an as-yet-unvisited element we have to find a 'new' number to match it with:"

data Tree a = Nil | Node a (Tree a) (Tree a) deriving (Show, Eq)
type Table a = [a]
numberTree :: Eq a => Tree a -> State (Table a) (Tree Int)
numberTree Nil = return Nil
numberTree (Node x t1 t2) = do
    num <- numberNode x
    nt1 <- numberTree t1
    nt2 <- numberTree t2
    return (Node num nt1 nt2)
  where
    numberNode :: Eq a => a -> State (Table a) Int
    numberNode x = do
        table <- get
        case elemIndex x table of
            Nothing -> do
                put (table ++ [x])
                return (length table)
            Just i -> return i

numTree applies numberTree with an initial state:

numTree :: (Eq a) => Tree a -> Tree Int
numTree t = evalState (numberTree t) []
testTree = Node "Zero" (Node "One" (Node "Two" Nil Nil) (Node "One" (Node "Zero" Nil Nil) Nil)) Nil
numTree testTree => Node 0 (Node 1 (Node 2 Nil Nil) (Node 1 (Node 0 Nil Nil) Nil)) Nil

Instances

11
  • instance (Generic s, Generic m, Generic a) => Generic (StateT s m a)
  • instance (Functor m) => Functor (StateT s m)
  • instance (Functor m, Monad m) => Applicative (StateT s m)
  • instance (Functor m, MonadPlus m) => Alternative (StateT s m)
  • instance (Monad m) => Monad (StateT s m)
  • instance (Fail.MonadFail m) => Fail.MonadFail (StateT s m)
  • instance (MonadPlus m) => MonadPlus (StateT s m)
  • instance (MonadFix m) => MonadFix (StateT s m)
  • instance MonadTrans (StateT s)
  • instance (MonadIO m) => MonadIO (StateT s m)
  • instance Contravariant m => Contravariant (StateT s m)
Maintainer
R.Paterson@city.ac.uk
Portability
portable
Copyright
(c) Andy Gill 2001, (c) Oregon Graduate Institute of Science and Technology, 2001
License
BSD-style (see the file LICENSE)
Build record and source files

Community contribution. The service has not verified this documentation.

Target: Linux on x86-64. Some inferred types and resolved links are not available.

Generator: aihc-haddock-858b1951-web-1

Metadata snapshot: ac77ab7d2b1e88487eeab41661abedb7bfb8bc846deb92e7874c08d166bff65d

Open the dependency plan · Download the documentation model

Import a package

Enter a package name and an exact version from Hackage. The site contains imported versions only.