Community
Modules 31

Data.Set

Finite Sets

The Set e type represents a set of elements of type e. Most operations require that e have an instance of the Ord class. A Set is strict in its elements.

When deciding if this is the correct data structure to use, consider:

  • If you are using Int keys, you will get much better performance for most operations using Data.IntSet.

  • If you don't care about ordering and don't handle untrusted elements, consider using Data.HashSet from the unordered-containers package instead.

For a walkthrough of the most commonly used functions see the sets introduction.

This module is intended to be imported qualified, to avoid name clashes with Prelude functions, e.g.

 import Data.Set (Set)
 import qualified Data.Set as Set

The Ord e instance is expected to be lawful and define a total order. Unless otherwise specified, operations expect equality to be extensional: if elements x1 and x2 satisfy x1 == x2, they are considered identical. For instance, if only one element must be retained by an operation, it is free to select either.

Warning

The size of the set must not exceed maxBound::Int. Violation of this condition is not detected and if the size limit is exceeded, its behaviour is undefined.

Implementation

The implementation of Set is based on size balanced binary trees (or trees of bounded balance) as described by:

Bounds for union, intersection, and difference are as given by

Performance information

The time complexity is given for each operation in [big-O notation](http:/en.wikipedia.orgwiki/Big_O_notation), with n referring to the number of entries in the set.

Operations like member, insert, and delete take O(\log n) time.

Binary set operations like union and intersection take O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr) time, where m and n are the sizes of the smaller and larger input sets respectively.

Set type

data Set a

A set of values a.

Construction

empty :: Set a

O(1). The empty set.

singleton :: a -> Set a

O(1). Create a singleton set.

fromList :: Ord a => [a] -> Set a

O(n \log n). Create a set from a list of elements.

If the elements are in non-decreasing order, this function takes O(n) time.

fromAscList :: Eq a => [a] -> Set a

O(n). Build a set from an ascending list in linear time.

Warning: This function should be used only if the elements are in non-decreasing order. This precondition is not checked. Use fromList if the precondition may not hold.

fromDescList :: Eq a => [a] -> Set a

O(n). Build a set from a descending list in linear time.

Warning: This function should be used only if the elements are in non-increasing order. This precondition is not checked. Use fromList if the precondition may not hold.

fromDistinctAscList :: [a] -> Set a

O(n). Build a set from an ascending list of distinct elements in linear time.

Warning: This function should be used only if the elements are in strictly increasing order. This precondition is not checked. Use fromList if the precondition may not hold.

fromDistinctDescList :: [a] -> Set a

O(n). Build a set from a descending list of distinct elements in linear time.

Warning: This function should be used only if the elements are in strictly decreasing order. This precondition is not checked. Use fromList if the precondition may not hold.

powerSet :: Set a -> Set (Set a)

O(2^n \log n). Calculate the power set of a set: the set of all its subsets.

t ``member`` powerSet s == t ``isSubsetOf`` s

Example:

powerSet (fromList [1,2,3]) =
  fromList $ map fromList [[],[1],[1,2],[1,2,3],[1,3],[2],[2,3],[3]]

Insertion

insert :: Ord a => a -> Set a -> Set a

O(\log n). Insert an element in a set. If the set already contains an element equal to the given value, it is replaced with the new value.

Deletion

delete :: Ord a => a -> Set a -> Set a

O(\log n). Delete an element from a set.

pop :: Ord a => a -> Set a -> Maybe (Set a)

O(\log n). Pop an element from the set.

Returns Nothing if the element is not a member of the set. Otherwise returns Just the set with the element removed.

pop 1 (fromList [0,2,4]) == Nothing
pop 2 (fromList [0,2,4]) == Just (fromList [0,4])

Generalized insertion/deletion

alterF :: (Ord a, Functor f) => (Bool -> f Bool) -> a -> Set a -> f (Set a)

O(\log n) (alterF f x s) can delete or insert x in s depending on whether an equal element is found in s.

In short:

'member' x \<$\> 'alterF' f x s = f ('member' x s)

Note that unlike insert, alterF will not replace an element equal to the given value.

Note: alterF is a variant of the at combinator from Control.Lens.At.

Examples

-- Get whether the element is a member, and also insert or remove it.
getAndSet :: Ord a => a -> Bool -> Set a -> (Bool, Set a)
getAndSet x new = alterF (\\old -> (old, new)) x
-- Delete the element. If it is absent the result is Nothing.
mustDelete :: Ord a => a -> Set a -> Maybe (Set a)
mustDelete = alterF (\\b -> if b then Just False else Nothing)

Query

member :: Ord a => a -> Set a -> Bool

O(\log n). Is the element in the set?

notMember :: Ord a => a -> Set a -> Bool

O(\log n). Is the element not in the set?

lookupLT :: Ord a => a -> Set a -> Maybe a

O(\log n). Find largest element smaller than the given one.

lookupLT 3 (fromList [3, 5]) == Nothing
lookupLT 5 (fromList [3, 5]) == Just 3

lookupGT :: Ord a => a -> Set a -> Maybe a

O(\log n). Find smallest element greater than the given one.

lookupGT 4 (fromList [3, 5]) == Just 5
lookupGT 5 (fromList [3, 5]) == Nothing

lookupLE :: Ord a => a -> Set a -> Maybe a

O(\log n). Find largest element smaller or equal to the given one.

lookupLE 2 (fromList [3, 5]) == Nothing
lookupLE 4 (fromList [3, 5]) == Just 3
lookupLE 5 (fromList [3, 5]) == Just 5

lookupGE :: Ord a => a -> Set a -> Maybe a

O(\log n). Find smallest element greater or equal to the given one.

lookupGE 3 (fromList [3, 5]) == Just 3
lookupGE 4 (fromList [3, 5]) == Just 5
lookupGE 6 (fromList [3, 5]) == Nothing

null :: Set a -> Bool

O(1). Is this the empty set?

size :: Set a -> Int

O(1). The number of elements in the set.

isSubsetOf :: Ord a => Set a -> Set a -> Bool

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. (s1 `isSubsetOf` s2) indicates whether s1 is a subset of s2.

s1 \`isSubsetOf\` s2 = all (``member`` s2) s1
s1 \`isSubsetOf\` s2 = null (s1 ``difference`` s2)
s1 \`isSubsetOf\` s2 = s1 ``union`` s2 == s2
s1 \`isSubsetOf\` s2 = s1 ``intersection`` s2 == s1

isProperSubsetOf :: Ord a => Set a -> Set a -> Bool

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. (s1 `isProperSubsetOf` s2) indicates whether s1 is a proper subset of s2.

s1 \`isProperSubsetOf\` s2 = s1 ``isSubsetOf`` s2 && s1 /= s2

disjoint :: Ord a => Set a -> Set a -> Bool

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. Check whether two sets are disjoint (i.e., their intersection is empty).

disjoint (fromList [2,4,6])   (fromList [1,3])     == True
disjoint (fromList [2,4,6,8]) (fromList [2,3,5,7]) == False
disjoint (fromList [1,2])     (fromList [1,2,3,4]) == False
disjoint (fromList [])        (fromList [])        == True
xs ``disjoint`` ys = null (xs ``intersection`` ys)

Combine

union :: Ord a => Set a -> Set a -> Set a

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. The union of two sets, preferring the first set when equal elements are encountered.

unions :: (Foldable f, Ord a) => f (Set a) -> Set a

The union of the sets in a Foldable structure : (unions == foldl union empty).

difference :: Ord a => Set a -> Set a -> Set a

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. Difference of two sets.

Return elements of the first set not existing in the second set.

difference (fromList [5, 3]) (fromList [5, 7]) == singleton 3

(\\) :: Ord a => Set a -> Set a -> Set a

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. See difference.

intersection :: Ord a => Set a -> Set a -> Set a

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. The intersection of two sets. Elements of the result come from the first set, so for example

import qualified Data.Set as S
data AB = A | B deriving Show
instance Ord AB where compare _ _ = EQ
instance Eq AB where _ == _ = True
main = print (S.singleton A `S.intersection` S.singleton B,
              S.singleton B `S.intersection` S.singleton A)

prints (fromList [A],fromList [B]).

intersections :: Ord a => NonEmpty (Set a) -> Set a

The intersection of a series of sets. Intersections are performed left-to-right.

symmetricDifference :: Ord a => Set a -> Set a -> Set a

O\bigl(m \log\bigl(\frac{n}{m}+1\bigr)\bigr), \; 0 < m \leq n. The symmetric difference of two sets.

The result contains elements that appear in exactly one of the two sets.

symmetricDifference (fromList [0,2,4,6]) (fromList [0,3,6,9]) == fromList [2,3,4,9]

cartesianProduct :: Set a -> Set b -> Set (a, b)

O(nm). Calculate the Cartesian product of two sets.

cartesianProduct xs ys = fromList $ liftA2 (,) (toList xs) (toList ys)

Example:

cartesianProduct (fromList [1,2]) (fromList [\'a\',\'b\']) =
  fromList [(1,\'a\'), (1,\'b\'), (2,\'a\'), (2,\'b\')]

disjointUnion :: Set a -> Set b -> Set (Either a b)

O(n+m). Calculate the disjoint union of two sets.

disjointUnion xs ys = map Left xs ``union`` map Right ys

Example:

disjointUnion (fromList [1,2]) (fromList ["hi", "bye"]) =
  fromList [Left 1, Left 2, Right "hi", Right "bye"]

Filter

filter :: (a -> Bool) -> Set a -> Set a

O(n). Keep all elements that satisfy the predicate.

filterA :: Applicative f => (a -> f Bool) -> Set a -> f (Set a)

O(n). Keep all elements that satisfy the Applicative predicate.

takeWhileAntitone :: (a -> Bool) -> Set a -> Set a

O(\log n). Take while a predicate on the elements holds. The user is responsible for ensuring that for all elements j and k in the set, j < k ==> p j >= p k. See note at spanAntitone.

takeWhileAntitone p = 'fromDistinctAscList' . 'Data.List.takeWhile' p . 'toList'
takeWhileAntitone p = 'filter' p

dropWhileAntitone :: (a -> Bool) -> Set a -> Set a

O(\log n). Drop while a predicate on the elements holds. The user is responsible for ensuring that for all elements j and k in the set, j < k ==> p j >= p k. See note at spanAntitone.

dropWhileAntitone p = 'fromDistinctAscList' . 'Data.List.dropWhile' p . 'toList'
dropWhileAntitone p = 'filter' (not . p)

spanAntitone :: (a -> Bool) -> Set a -> (Set a, Set a)

O(\log n). Divide a set at the point where a predicate on the elements stops holding. The user is responsible for ensuring that for all elements j and k in the set, j < k ==> p j >= p k.

spanAntitone p xs = ('takeWhileAntitone' p xs, 'dropWhileAntitone' p xs)
spanAntitone p xs = partition p xs

Note: if p is not actually antitone, then spanAntitone will split the set at some unspecified point where the predicate switches from holding to not holding (where the predicate is seen to hold before the first element and to fail after the last element).

mapMaybe :: Ord b => (a -> Maybe b) -> Set a -> Set b

O(n \log n). Map elements and collect the Just results.

If the function is monotonically non-decreasing, this function takes O(n) time.

partition :: (a -> Bool) -> Set a -> (Set a, Set a)

O(n). Partition the set into two sets, one with all elements that satisfy the predicate and one with all elements that don't satisfy the predicate. See also split.

split :: Ord a => a -> Set a -> (Set a, Set a)

O(\log n). The expression (split x set) is a pair (set1,set2) where set1 comprises the elements of set less than x and set2 comprises the elements of set greater than x.

splitMember :: Ord a => a -> Set a -> (Set a, Bool, Set a)

O(\log n). Performs a split but also returns whether the pivot element was found in the original set.

splitRoot :: Set a -> [Set a]

O(1). Decompose a set into pieces based on the structure of the underlying tree. This function is useful for consuming a set in parallel.

No guarantee is made as to the sizes of the pieces; an internal, but deterministic process determines this. However, it is guaranteed that the pieces returned will be in ascending order (all elements in the first subset less than all elements in the second, and so on).

Examples:

splitRoot (fromList [1..6]) ==
  [fromList [1,2,3],fromList [4],fromList [5,6]]
splitRoot empty == []

Note that the current implementation does not return more than three subsets, but you should not depend on this behaviour because it can change in the future without notice.

Indexed

lookupIndex :: Ord a => a -> Set a -> Maybe Int

O(\log n). Look up the index of an element, which is its zero-based index in the sorted sequence of elements. The index is a number from 0 up to, but not including, the size of the set.

isJust   (lookupIndex 2 (fromList [5,3])) == False
fromJust (lookupIndex 3 (fromList [5,3])) == 0
fromJust (lookupIndex 5 (fromList [5,3])) == 1
isJust   (lookupIndex 6 (fromList [5,3])) == False

findIndex :: Ord a => a -> Set a -> Int

O(\log n). Return the index of an element, which is its zero-based index in the sorted sequence of elements. The index is a number from 0 up to, but not including, the size of the set. Calls error when the element is not a member of the set.

Note: This function is partial. Prefer lookupIndex.

findIndex 2 (fromList [5,3])    Error: element is not in the set
findIndex 3 (fromList [5,3]) == 0
findIndex 5 (fromList [5,3]) == 1
findIndex 6 (fromList [5,3])    Error: element is not in the set

elemAt :: Int -> Set a -> a

O(\log n). Retrieve an element by its index, i.e. by its zero-based index in the sorted sequence of elements. If the index is out of range (less than zero, greater or equal to size of the set), error is called.

Note: This function is partial.

elemAt 0 (fromList [5,3]) == 3
elemAt 1 (fromList [5,3]) == 5
elemAt 2 (fromList [5,3])    Error: index out of range

deleteAt :: Int -> Set a -> Set a

O(\log n). Delete the element at index, i.e. by its zero-based index in the sorted sequence of elements. If the index is out of range (less than zero, greater or equal to size of the set), error is called.

Note: This function is partial.

deleteAt 0    (fromList [5,3]) == singleton 5
deleteAt 1    (fromList [5,3]) == singleton 3
deleteAt 2    (fromList [5,3])    Error: index out of range
deleteAt (-1) (fromList [5,3])    Error: index out of range

take :: Int -> Set a -> Set a

O(\log n). Take a given number of elements in order, beginning with the smallest ones.

take n = 'fromDistinctAscList' . 'Prelude.take' n . 'toAscList'

drop :: Int -> Set a -> Set a

O(\log n). Drop a given number of elements in order, beginning with the smallest ones.

drop n = 'fromDistinctAscList' . 'Prelude.drop' n . 'toAscList'

splitAt :: Int -> Set a -> (Set a, Set a)

O(\log n). Split a set at a particular index.

splitAt !n !xs = ('take' n xs, 'drop' n xs)

Map

map :: Ord b => (a -> b) -> Set a -> Set b

O(n \log n). map f s is the set obtained by applying f to each element of s.

If `f` is monotonically non-decreasing, this function takes O(n) time.

It's worth noting that the size of the result may be smaller if, for some (x,y), x /= y && f x == f y

mapMonotonic :: (a -> b) -> Set a -> Set b

O(n). mapMonotonic f s == map f s, but works only when f is strictly increasing. Semi-formally, we have:

and [x < y ==> f x < f y | x <- ls, y <- ls]
                    ==> mapMonotonic f s == map f s
    where ls = toList s

Warning: This function should be used only if f is monotonically strictly increasing. This precondition is not checked. Use map if the precondition may not hold.

Folds

foldr :: (a -> b -> b) -> b -> Set a -> b

O(n). Fold the elements in the set using the given right-associative binary operator, such that foldr f z == foldr f z . toAscList.

For example,

toAscList set = foldr (:) [] set

foldl :: (a -> b -> a) -> a -> Set b -> a

O(n). Fold the elements in the set using the given left-associative binary operator, such that foldl f z == foldl f z . toAscList.

For example,

toDescList set = foldl (flip (:)) [] set

Strict folds

foldr' :: (a -> b -> b) -> b -> Set a -> b

O(n). A strict version of foldr. Each application of the operator is evaluated before using the result in the next application. This function is strict in the starting value.

foldl' :: (a -> b -> a) -> a -> Set b -> a

O(n). A strict version of foldl. Each application of the operator is evaluated before using the result in the next application. This function is strict in the starting value.

Legacy folds

fold :: (a -> b -> b) -> b -> Set a -> b

Use Data.Set.foldr instead

O(n). Fold the elements in the set using the given right-associative binary operator.

Min/Max

lookupMin :: Set a -> Maybe a

O(\log n). The minimal element of the set. Returns Nothing if the set is empty.

lookupMax :: Set a -> Maybe a

O(\log n). The maximal element of the set. Returns Nothing if the set is empty.

deleteMin :: Set a -> Set a

O(\log n). Delete the minimal element. Returns an empty set if the set is empty.

deleteMax :: Set a -> Set a

O(\log n). Delete the maximal element. Returns an empty set if the set is empty.

maxView :: Set a -> Maybe (a, Set a)

O(\log n). Retrieves the maximal key of the set, and the set stripped of that element, or Nothing if passed an empty set.

minView :: Set a -> Maybe (a, Set a)

O(\log n). Retrieves the minimal key of the set, and the set stripped of that element, or Nothing if passed an empty set.

findMin :: Set a -> a

O(\log n). The minimal element of the set. Calls error if the set is empty.

Note: This function is partial. Prefer lookupMin.

findMax :: Set a -> a

O(\log n). The maximal element of the set. Calls error if the set is empty.

Note: This function is partial. Prefer lookupMax.

deleteFindMin :: Set a -> (a, Set a)

O(\log n). Delete and find the minimal element.

Calls error if the set is empty.

Note: This function is partial. Prefer minView.

deleteFindMax :: Set a -> (a, Set a)

O(\log n). Delete and find the maximal element.

Calls error if the set is empty.

Note: This function is partial. Prefer maxView.

Conversion

List

elems :: Set a -> [a]

O(n). An alias of toAscList. The elements of a set in ascending order. Subject to list fusion.

toList :: Set a -> [a]

O(n). Convert the set to a list of elements. Subject to list fusion.

toAscList :: Set a -> [a]

O(n). Convert the set to an ascending list of elements. Subject to list fusion.

toDescList :: Set a -> [a]

O(n). Convert the set to a descending list of elements. Subject to list fusion.

Debugging

showTree :: Show a => Set a -> String

O(n \log n). Show the tree that implements the set. The tree is shown in a compressed, hanging format.

showTreeWith :: Show a => Bool -> Bool -> Set a -> String

O(n \log n). The expression (showTreeWith hang wide map) shows the tree that implements the set. If hang is True, a hanging tree is shown otherwise a rotated tree is shown. If wide is True, an extra wide version is shown.

Set> putStrLn $ showTreeWith True False $ fromDistinctAscList [1..5]
4
+--2
|  +--1
|  +--3
+--5

Set> putStrLn $ showTreeWith True True $ fromDistinctAscList [1..5]
4
|
+--2
|  |
|  +--1
|  |
|  +--3
|
+--5

Set> putStrLn $ showTreeWith False True $ fromDistinctAscList [1..5]
+--5
|
4
|
|  +--3
|  |
+--2
   |
   +--1

valid :: Ord a => Set a -> Bool

O(n). Test if the internal set structure is valid.

Maintainer
libraries@haskell.org
Portability
portable
Copyright
(c) Daan Leijen 2002
License
BSD-style
Build record and source files

Community contribution. The service has not verified this documentation. The generator reported 15 diagnostics.

Target: Linux on x86-64. Some inferred types and resolved links are not available.

Generator: aihc-haddock-aa6debbd-web-3

Metadata snapshot: 634f718c0d8cd970c4e2c511d2345d8fd36c6dc32b06343c2b4e914ffccbce7f

Open the dependency plan · Download the documentation model

Import a package

Enter a package name and an exact version from Hackage. The site contains imported versions only.