data Text
A space efficient, packed, unboxed Unicode text type.
License : BSD-style Maintainer : bos@serpentine.com Portability : GHC
A time and space-efficient implementation of Unicode text. Suitable for performance critical use, both in terms of large data quantities and high speed.
Note: Read below the synopsis for important notes on the use of this module.
This module is intended to be imported qualified, to avoid name
clashes with Prelude functions, e.g.
import qualified Data.Text as T
To use an extended and very rich family of functions for working with Unicode text (including normalization, regular expressions, non-standard encodings, text breaking, and locales), see the text-icu package.
This package provides both strict and lazy Text types. The
strict type is provided by the Data.Text module, while the lazy
type is provided by the Data.Text.Lazy module. Internally, the
lazy Text type consists of a list of strict chunks.
The strict Text type requires that an entire string fit into
memory at once. The lazy Text type is capable of
streaming strings that are larger than memory using a small memory
footprint. In many cases, the overhead of chunked streaming makes
the lazy Text type slower than its strict
counterpart, but this is not always the case. Sometimes, the time
complexity of a function in one module may be different from the
other, due to their differing internal structures.
Each module provides an almost identical API, with the main
difference being that the strict module uses Int values for
lengths and counts, while the lazy module uses Int64
lengths.
A Text value is a sequence of Unicode scalar values, as defined
in
§3.9, definition D76 of the Unicode 5.2 standard.
As such, a Text cannot contain values in the range U+D800 to
U+DFFF inclusive. Haskell implementations admit all Unicode code
points
(§3.4, definition D10)
as Char values, including code points from this invalid range.
This means that there are some Char values
(corresponding to Surrogate category) that are not valid
Unicode scalar values, and the functions in this module must handle
those cases.
Within this module, many functions construct a Text from one or
more Char values. Those functions will substitute Char values
that are not valid Unicode scalar values with the replacement
character "�" (U+FFFD). Functions that perform this
inspection and replacement are documented with the phrase
"Performs replacement on invalid scalar values". The functions replace
invalid scalar values, instead of dropping them, as a security
measure. For details, see
Unicode Technical Report 36, §3.5.)
This package uses the term character to denote Unicode code points.
Note that this is not the same thing as a grapheme (e.g. a
composition of code points that form one visual symbol). For
instance, consider the grapheme "ä". This symbol has two
Unicode representations: a single code-point representation
U+00E4 (the LATIN SMALL LETTER A WITH DIAERESIS code point),
and a two code point representation U+0061 (the "A" code
point) and U+0308 (the COMBINING DIAERESIS code point).
Starting from text-1.3 fusion is no longer implicit,
and pipelines of transformations usually allocate intermediate Text values.
Users, who observe significant changes to performances,
are encouraged to use fusion framework explicitly, employing
Data.Text.Internal.Fusion and Data.Text.Internal.Fusion.Common.
data TextA space efficient, packed, unboxed Unicode text type.
type StrictText = TextType synonym for the strict flavour of Text.
pack :: String -> TextO(n) Convert a String into a Text.
Performs replacement on invalid scalar values, so is not unpack . packid:
>>> Data.Text.unpack (pack "\55555")
"\65533"
unpack :: Text -> StringO(n) Convert a Text into a String.
singleton :: Char -> TextO(1) Convert a character into a Text. Performs replacement on invalid scalar values.
empty :: TextO(1) The empty Text.
Empty :: TextBidirectional pattern synonym for empty and null (both O(1)),
to be used together with :< or :>.
(:<) :: Char -> Text -> TextBidirectional pattern synonym for cons (O(n)) and uncons (O(1)),
to be used together with Empty.
(:>) :: Text -> Char -> TextBidirectional pattern synonym for snoc (O(n)) and unsnoc (O(1))
to be used together with Empty.
cons :: Char -> Text -> TextO(n) Adds a character to the front of a Text. This function
is more costly than its List counterpart because it requires
copying a new array. Performs replacement on
invalid scalar values.
snoc :: Text -> Char -> TextO(n) Adds a character to the end of a Text. This copies the
entire array in the process.
Performs replacement on invalid scalar values.
append :: Text -> Text -> TextO(n) Appends one Text to the other by copying both of them
into a new Text.
uncons :: Text -> Maybe (Char, Text)O(1) Returns the first character and rest of a Text, or
Nothing if empty.
unsnoc :: Text -> Maybe (Text, Char)O(1) Returns all but the last character and the last character of a
Text, or Nothing if empty.
head :: HasCallStack => Text -> CharO(1) Returns the first character of a Text, which must be
non-empty. This is a partial function, consider using uncons instead.
last :: HasCallStack => Text -> CharO(1) Returns the last character of a Text, which must be
non-empty. This is a partial function, consider using unsnoc instead.
tail :: HasCallStack => Text -> TextO(1) Returns all characters after the head of a Text, which
must be non-empty. This is a partial function, consider using uncons instead.
init :: HasCallStack => Text -> TextO(1) Returns all but the last character of a Text, which must
be non-empty. This is a partial function, consider using unsnoc instead.
null :: Text -> BoolO(1) Tests whether a Text is empty or not.
length :: Text -> IntO(n) Returns the number of characters in a Text.
compareLength :: Text -> Int -> OrderingO(min(n,c)) Compare the count of characters in a Text to a number.
'compareLength' t c = 'P.compare' ('length' t) c
This function gives the same answer as comparing against the result
of length, but can short circuit if the count of characters is
greater than the number, and hence be more efficient.
map :: (Char -> Char) -> Text -> Textintercalate :: Text -> [Text] -> TextO(n) The intercalate function takes a Text and a list of
Texts and concatenates the list after interspersing the first
argument between each element of the list.
Example:
>>> T.intercalate "NI!" ["We", "seek", "the", "Holy", "Grail"]
"WeNI!seekNI!theNI!HolyNI!Grail"
intersperse :: Char -> Text -> TextO(n) The intersperse function takes a character and places it
between the characters of a Text.
Example:
>>> T.intersperse '.' "SHIELD"
"S.H.I.E.L.D"
Performs replacement on invalid scalar values.
transpose :: [Text] -> [Text]O(n) The transpose function transposes the rows and columns
of its Text argument. Note that this function uses pack,
unpack, and the list version of transpose, and is thus not very
efficient.
Examples:
>>> transpose ["green","orange"]
["go","rr","ea","en","ng","e"]
>>> transpose ["blue","red"]
["br","le","ud","e"]
reverse :: Text -> TextO(n) Reverse the characters of a string.
Example:
replace :: HasCallStack => Text -> Text -> Text -> TextO(m+n) Replace every non-overlapping occurrence of needle in
haystack with replacement.
This function behaves as though it was defined as follows:
replace needle replacement haystack =
'intercalate' replacement ('splitOn' needle haystack)
As this suggests, each occurrence is replaced exactly once. So if
needle occurs in replacement, that occurrence will not itself
be replaced recursively:
>>> replace "oo" "foo" "oo"
"foo"
In cases where several instances of needle overlap, only the
first one will be replaced:
>>> replace "ofo" "bar" "ofofo"
"barfo"
In (unlikely) bad cases, this function's time complexity degrades towards O(n*m).
Textneedle to search for. If this string is empty, an
error will occur.
Textreplacement to replace needle with.
Texthaystack in which to search.
When case converting Text values, do not use combinators like
map toUpper to case convert each character of a string
individually, as this gives incorrect results according to the
rules of some writing systems. The whole-string case conversion
functions from this module, such as toUpper, obey the correct
case conversion rules. As a result, these functions may map one
input character to two or three output characters. For examples,
see the documentation of each function.
Note: In some languages, case conversion is a locale- and context-dependent operation. The case conversion functions in this module are not locale sensitive. Programs that require locale sensitivity should use appropriate versions of the case mapping functions from the text-icu package.
toCaseFold :: Text -> TextO(n) Convert a string to folded case.
This function is mainly useful for performing caseless (also known as case insensitive) string comparisons.
A string x is a caseless match for a string y if and only if:
toCaseFold x == toCaseFold y
The result string may be longer than the input string, and may
differ from applying toLower to the input string. For instance,
the Armenian small ligature "ﬓ" (men now, U+FB13) is case
folded to the sequence "մ" (men, U+0574) followed by
"ն" (now, U+0576), while the Greek "µ" (micro sign,
U+00B5) is case folded to "μ" (small letter mu, U+03BC)
instead of itself.
toLower :: Text -> TextO(n) Convert a string to lower case, using simple case conversion.
The result string may be longer than the input string. For instance, "İ" (Latin capital letter I with dot above, U+0130) maps to the sequence "i" (Latin small letter i, U+0069) followed by " ̇" (combining dot above, U+0307).
toUpper :: Text -> TextO(n) Convert a string to upper case, using simple case conversion.
The result string may be longer than the input string. For instance, the German "ß" (eszett, U+00DF) maps to the two-letter sequence "SS".
toTitle :: Text -> TextO(n) Convert a string to title case, using simple case conversion.
The first letter (as determined by isLetter)
of the input is converted to title case, as is
every subsequent letter that immediately follows a non-letter.
Every letter that immediately follows another letter is converted
to lower case.
This function is not idempotent.
Consider lower-case letter ʼn (U+0149 LATIN SMALL LETTER N PRECEDED BY APOSTROPHE).
Then toTitle "ʼn" = "ʼN": the first (and the only) letter of the input
is converted to title case, becoming two letters.
Now ʼ (U+02BC MODIFIER LETTER APOSTROPHE) is a modifier letter
and as such is recognised as a letter by isLetter,
so toTitle "ʼN" = "'n".
The result string may be longer than the input string. For example, the Latin small ligature fl (U+FB02) is converted to the sequence Latin capital letter F (U+0046) followed by Latin small letter l (U+006C).
Note: this function does not take language or culture specific rules into account. For instance, in English, different style guides disagree on whether the book name "The Hill of the Red Fox" is correctly title cased—but this function will capitalize every word.
justifyLeft :: Int -> Char -> Text -> TextO(n) Left-justify a string to the given length, using the specified fill character on the right. Performs replacement on invalid scalar values.
Examples:
>>> justifyLeft 7 'x' "foo"
"fooxxxx"
>>> justifyLeft 3 'x' "foobar"
"foobar"
justifyRight :: Int -> Char -> Text -> TextO(n) Right-justify a string to the given length, using the specified fill character on the left. Performs replacement on invalid scalar values.
Examples:
>>> justifyRight 7 'x' "bar"
"xxxxbar"
>>> justifyRight 3 'x' "foobar"
"foobar"
center :: Int -> Char -> Text -> TextO(n) Center a string to the given length, using the specified fill character on either side. Performs replacement on invalid scalar values.
Examples:
>>> center 8 'x' "HS"
"xxxHSxxx"
foldl :: (a -> Char -> a) -> a -> Text -> aO(n) foldl, applied to a binary operator, a starting value
(typically the left-identity of the operator), and a Text,
reduces the Text using the binary operator, from left to right.
foldl' :: (a -> Char -> a) -> a -> Text -> aO(n) A strict version of foldl.
foldl1 :: HasCallStack => (Char -> Char -> Char) -> Text -> CharO(n) A variant of foldl that has no starting value argument,
and thus must be applied to a non-empty Text.
foldl1' :: HasCallStack => (Char -> Char -> Char) -> Text -> CharO(n) A strict version of foldl1.
foldr :: (Char -> a -> a) -> a -> Text -> aO(n) foldr, applied to a binary operator, a starting value
(typically the right-identity of the operator), and a Text,
reduces the Text using the binary operator, from right to left.
If the binary operator is strict in its second argument, use foldr'
instead.
foldr is lazy like foldr for lists: evaluation actually
traverses the Text from left to right, only as far as it needs to.
For example, head can be defined with O(1) complexity using foldr:
head :: Text -> Char
head = foldr const (error "head empty")
Searches from left to right with short-circuiting behavior can
also be defined using foldr (e.g., any, all, find, elem).
foldr' :: (Char -> a -> a) -> a -> Text -> aO(n) A strict version of foldr.
foldr' evaluates as a right-to-left traversal using constant stack space.
foldr1 :: HasCallStack => (Char -> Char -> Char) -> Text -> CharO(n) A variant of foldr that has no starting value argument,
and thus must be applied to a non-empty Text.
foldlM' :: Monad m => (a -> Char -> m a) -> a -> Text -> m aO(n) A monadic version of foldl'.
concat :: [Text] -> TextO(n) Concatenate a list of Texts.
concatMap :: (Char -> Text) -> Text -> TextO(n) Map a function over a Text that results in a Text, and
concatenate the results.
any :: (Char -> Bool) -> Text -> BoolO(n) any p t determines whether any character in the
Text t satisfies the predicate p.
all :: (Char -> Bool) -> Text -> BoolO(n) all p t determines whether all characters in the
Text t satisfy the predicate p.
maximum :: HasCallStack => Text -> CharO(n) maximum returns the maximum value from a Text, which
must be non-empty.
minimum :: HasCallStack => Text -> CharO(n) minimum returns the minimum value from a Text, which
must be non-empty.
isAscii :: Text -> BoolO(n) Test whether Text contains only ASCII code-points (i.e. only
U+0000 through U+007F).
This is a more efficient version of .all isAscii
>>> isAscii ""
True>>> isAscii "abc\NUL"
True>>> isAscii "abcd€"
FalseisAscii t == all (< '\x80') tscanl :: (Char -> Char -> Char) -> Char -> Text -> Textscanl1 :: (Char -> Char -> Char) -> Text -> TextO(n) scanl1 is a variant of scanl that has no starting
value argument. Performs replacement on invalid scalar values.
scanl1 f [x1, x2, ...] == [x1, x1 `f` x2, ...]
scanr :: (Char -> Char -> Char) -> Char -> Text -> TextO(n) scanr is the right-to-left dual of scanl. Performs
replacement on invalid scalar values.
scanr f v == reverse . scanl (flip f) v . reverse
scanr1 :: (Char -> Char -> Char) -> Text -> TextO(n) scanr1 is a variant of scanr that has no starting
value argument. Performs replacement on invalid scalar values.
mapAccumL :: forall a. (a -> Char -> (a, Char)) -> a -> Text -> (a, Text)O(n) Like a combination of map and foldl'. Applies a
function to each element of a Text, passing an accumulating
parameter from left to right, and returns a final Text. Performs
replacement on invalid scalar values.
mapAccumR :: forall a. (a -> Char -> (a, Char)) -> a -> Text -> (a, Text)The mapAccumR function behaves like a combination of map and
a strict foldr; it applies a function to each element of a
Text, passing an accumulating parameter from right to left, and
returning a final value of this accumulator together with the new
Text.
Performs replacement on invalid scalar values.
replicate :: Int -> Text -> TextO(n*m) replicate n t is a Text consisting of the input
t repeated n times.
unfoldr :: (a -> Maybe (Char, a)) -> a -> TextO(n), where n is the length of the result. The unfoldr
function is analogous to the List unfoldr. unfoldr builds a
Text from a seed value. The function takes the element and
returns Nothing if it is done producing the Text, otherwise
Just (a,b). In this case, a is the next Char in the
string, and b is the seed value for further production.
Performs replacement on invalid scalar values.
unfoldrN :: Int -> (a -> Maybe (Char, a)) -> a -> TextO(n) Like unfoldr, unfoldrN builds a Text from a seed
value. However, the length of the result should be limited by the
first argument to unfoldrN. This function is more efficient than
unfoldr when the maximum length of the result is known and
correct, otherwise its performance is similar to unfoldr.
Performs replacement on invalid scalar values.
take :: Int -> Text -> TextO(n) take n, applied to a Text, returns the prefix of the
Text of length n, or the Text itself if n is greater than
the length of the Text.
takeEnd :: Int -> Text -> TextO(n) takeEnd n t returns the suffix remaining after
taking n characters from the end of t.
Examples:
>>> takeEnd 3 "foobar"
"bar"
drop :: Int -> Text -> TextO(n) drop n, applied to a Text, returns the suffix of the
Text after the first n characters, or the empty Text if n
is greater than the length of the Text.
dropEnd :: Int -> Text -> TextO(n) dropEnd n t returns the prefix remaining after
dropping n characters from the end of t.
Examples:
>>> dropEnd 3 "foobar"
"foo"
takeWhile :: (Char -> Bool) -> Text -> TextO(n) takeWhile, applied to a predicate p and a Text,
returns the longest prefix (possibly empty) of elements that
satisfy p.
takeWhileEnd :: (Char -> Bool) -> Text -> TextO(n) takeWhileEnd, applied to a predicate p and a Text,
returns the longest suffix (possibly empty) of elements that
satisfy p.
Examples:
>>> takeWhileEnd (=='o') "foo"
"oo"
dropWhile :: (Char -> Bool) -> Text -> TextO(n) dropWhile p t returns the suffix remaining after
takeWhile p t.
dropWhileEnd :: (Char -> Bool) -> Text -> TextO(n) dropWhileEnd p t returns the prefix remaining after
dropping characters that satisfy the predicate p from the end of
t.
Examples:
>>> dropWhileEnd (=='.') "foo..."
"foo"
dropAround :: (Char -> Bool) -> Text -> TextO(n) dropAround p t returns the substring remaining after
dropping characters that satisfy the predicate p from both the
beginning and end of t.
strip :: Text -> TextO(n) Remove leading and trailing white space from a string. Equivalent to:
dropAround isSpace
stripStart :: Text -> TextO(n) Remove leading white space from a string. Equivalent to:
dropWhile isSpace
stripEnd :: Text -> TextO(n) Remove trailing white space from a string. Equivalent to:
dropWhileEnd isSpace
splitAt :: Int -> Text -> (Text, Text)O(n) splitAt n t returns a pair whose first element is a
prefix of t of length n, and whose second is the remainder of
the string. It is equivalent to (.
take n t, drop n t)
breakOn :: HasCallStack => Text -> Text -> (Text, Text)O(n+m) Find the first instance of needle (which must be
non-null) in haystack. The first element of the returned tuple
is the prefix of haystack before needle is matched. The second
is the remainder of haystack, starting with the match.
Examples:
>>> breakOn "::" "a::b::c"
("a","::b::c")
>>> breakOn "/" "foobar"
("foobar","")
Laws:
append prefix match == haystack
where (prefix, match) = breakOn needle haystack
If you need to break a string by a substring repeatedly (e.g. you
want to break on every instance of a substring), use breakOnAll
instead, as it has lower startup overhead.
In (unlikely) bad cases, this function's time complexity degrades towards O(n*m).
breakOnEnd :: HasCallStack => Text -> Text -> (Text, Text)O(n+m) Similar to breakOn, but searches from the end of the
string.
The first element of the returned tuple is the prefix of haystack
up to and including the last match of needle. The second is the
remainder of haystack, following the match.
>>> breakOnEnd "::" "a::b::c"
("a::b::","c")
break :: (Char -> Bool) -> Text -> (Text, Text)O(n) break is like span, but the prefix returned is
over elements that fail the predicate p.
>>> T.break (=='c') "180cm"
("180","cm")
span :: (Char -> Bool) -> Text -> (Text, Text)O(n) span, applied to a predicate p and text t, returns
a pair whose first element is the longest prefix (possibly empty)
of t of elements that satisfy p, and whose second is the
remainder of the text.
>>> T.span (=='0') "000AB"
("000","AB")
spanM :: Monad m => (Char -> m Bool) -> Text -> m (Text, Text)O(length of prefix) spanM, applied to a monadic predicate p,
a text t, returns a pair (t1, t2) where t1 is the longest prefix of
t whose elements satisfy p, and t2 is the remainder of the text.
>>> T.spanM (\c -> state $ \i -> (fromEnum c == i, i+1)) "abcefg" `runState` 97
(("abc","efg"),101)
span is spanM specialized to Identity:
-- for all p :: Char -> Bool
'span' p = 'Data.Functor.Identity.runIdentity' . 'spanM' ('pure' . p)
spanEndM :: Monad m => (Char -> m Bool) -> Text -> m (Text, Text)O(length of suffix) spanEndM, applied to a monadic predicate p,
a text t, returns a pair (t1, t2) where t2 is the longest suffix of
t whose elements satisfy p, and t1 is the remainder of the text.
>>> T.spanEndM (\c -> state $ \i -> (fromEnum c == i, i-1)) "tuvxyz" `runState` 122
(("tuv","xyz"),118)
'spanEndM' p . 'reverse' = fmap ('Data.Bifunctor.bimap' 'reverse' 'reverse') . 'spanM' p
group :: Text -> [Text]O(n) Group characters in a string by equality.
groupBy :: (Char -> Char -> Bool) -> Text -> [Text]O(n) Group characters in a string according to a predicate.
inits :: Text -> [Text]O(n) Return all initial segments of the given Text, shortest
first.
initsNE :: Text -> NonEmptyList.NonEmpty TextO(n) Return all initial segments of the given Text, shortest
first.
tails :: Text -> [Text]O(n) Return all final segments of the given Text, longest
first.
tailsNE :: Text -> NonEmptyList.NonEmpty TextO(n) Return all final segments of the given Text, longest
first.
Splitting functions in this library do not perform character-wise
copies to create substrings; they just construct new Texts that
are slices of the original.
splitOn :: HasCallStack => Text -> Text -> [Text]O(m+n) Break a Text into pieces separated by the first Text
argument (which cannot be empty), consuming the delimiter. An empty
delimiter is invalid, and will cause an error to be raised.
Examples:
>>> splitOn "\r\n" "a\r\nb\r\nd\r\ne"
["a","b","d","e"]
>>> splitOn "aaa" "aaaXaaaXaaaXaaa"
["","X","X","X",""]
>>> splitOn "x" "x"
["",""]
and
intercalate s . splitOn s == id
splitOn (singleton c) == split (==c)
(Note: the string s to split on above cannot be empty.)
In (unlikely) bad cases, this function's time complexity degrades towards O(n*m).
TextString to split on. If this string is empty, an error will occur.
TextInput text.
split :: (Char -> Bool) -> Text -> [Text]O(n) Splits a Text into components delimited by separators,
where the predicate returns True for a separator element. The
resulting components do not contain the separators. Two adjacent
separators result in an empty component in the output. eg.
>>> split (=='a') "aabbaca"
["","","bb","c",""]
>>> split (=='a') ""
[""]
chunksOf :: Int -> Text -> [Text]O(n) Splits a Text into components of length k. The last
element may be shorter than the other chunks, depending on the
length of the input. Examples:
>>> chunksOf 3 "foobarbaz"
["foo","bar","baz"]
>>> chunksOf 4 "haskell.org"
["hask","ell.","org"]
lines :: Text -> [Text]O(n) Breaks a Text up into a list of Texts at newline characters
'\n' (LF, line feed). The resulting strings do not contain newlines.
lines does not treat '\r' (CR, carriage return) as a newline character.
words :: Text -> [Text]O(n) Breaks a Text up into a list of words, delimited by Chars
representing white space.
unlines :: [Text] -> TextO(n) Joins lines, after appending a terminating newline to each.
unwords :: [Text] -> TextO(n) Joins words using single space characters.
isPrefixOf :: Text -> Text -> BoolO(n) The isPrefixOf function takes two Texts and returns
True if and only if the first is a prefix of the second.
isSuffixOf :: Text -> Text -> BoolO(n) The isSuffixOf function takes two Texts and returns
True if and only if the first is a suffix of the second.
isInfixOf :: Text -> Text -> BoolO(n+m) The isInfixOf function takes two Texts and returns
True if and only if the first is contained, wholly and intact, anywhere
within the second.
In (unlikely) bad cases, this function's time complexity degrades towards O(n*m).
stripPrefix :: Text -> Text -> Maybe TextO(n) Return the suffix of the second string if its prefix matches the entire first string.
Examples:
>>> stripPrefix "foo" "foobar"
Just "bar"
>>> stripPrefix "" "baz"
Just "baz"
>>> stripPrefix "foo" "quux"
Nothing
This is particularly useful with the ViewPatterns extension to
GHC, as follows:
{-# LANGUAGE ViewPatterns #-}
import Data.Text as T
fnordLength :: Text -> Int
fnordLength (stripPrefix "fnord" -> Just suf) = T.length suf
fnordLength _ = -1
stripSuffix :: Text -> Text -> Maybe TextO(n) Return the prefix of the second string if its suffix matches the entire first string.
Examples:
>>> stripSuffix "bar" "foobar"
Just "foo"
>>> stripSuffix "" "baz"
Just "baz"
>>> stripSuffix "foo" "quux"
Nothing
This is particularly useful with the ViewPatterns extension to
GHC, as follows:
{-# LANGUAGE ViewPatterns #-}
import Data.Text as T
quuxLength :: Text -> Int
quuxLength (stripSuffix "quux" -> Just pre) = T.length pre
quuxLength _ = -1
commonPrefixes :: Text -> Text -> Maybe (Text, Text, Text)O(n) Find the longest non-empty common prefix of two strings and return it, along with the suffixes of each string at which they no longer match.
If the strings do not have a common prefix or either one is empty,
this function returns Nothing.
Examples:
>>> commonPrefixes "foobar" "fooquux"
Just ("foo","bar","quux")
>>> commonPrefixes "veeble" "fetzer"
Nothing
>>> commonPrefixes "" "baz"
Nothing
filter :: (Char -> Bool) -> Text -> TextO(n) filter, applied to a predicate and a Text,
returns a Text containing those characters that satisfy the
predicate.
breakOnAll :: HasCallStack => Text -> Text -> [(Text, Text)]O(n+m) Find all non-overlapping instances of needle in
haystack. Each element of the returned list consists of a pair:
The entire string prior to the kth match (i.e. the prefix)
The kth match, followed by the remainder of the string
Examples:
>>> breakOnAll "::" ""
[]
>>> breakOnAll "/" "a/b/c/"
[("a","/b/c/"),("a/b","/c/"),("a/b/c","/")]
In (unlikely) bad cases, this function's time complexity degrades towards O(n*m).
The needle parameter may not be empty.
Textneedle to search for
Texthaystack in which to search
find :: (Char -> Bool) -> Text -> Maybe CharO(n) The find function takes a predicate and a Text, and
returns the first element matching the predicate, or Nothing if
there is no such element.
elem :: Char -> Text -> BoolO(n) The elem function takes a character and a Text, and
returns True if the element is found in the given Text, or
False otherwise.
partition :: (Char -> Bool) -> Text -> (Text, Text)O(n) The partition function takes a predicate and a Text,
and returns the pair of Texts with elements which do and do not
satisfy the predicate, respectively; i.e.
partition p t == (filter p t, filter (not . p) t)
If you think of a Text value as an array of Char values (which
it is not), you run the risk of writing inefficient code.
An idiom that is common in some languages is to find the numeric
offset of a character or substring, then use that number to split
or trim the searched string. With a Text value, this approach
would require two O(n) operations: one to perform the search, and
one to operate from wherever the search ended.
For example, suppose you have a string that you want to split on
the substring "::", such as "foo::bar::quux". Instead of
searching for the index of "::" and taking the substrings
before and after that index, you would instead use breakOnAll "::".
index :: HasCallStack => Text -> Int -> CharO(n) Text index (subscript) operator, starting from 0.
findIndex :: (Char -> Bool) -> Text -> Maybe IntO(n) The findIndex function takes a predicate and a Text
and returns the index of the first element in the Text satisfying
the predicate.
count :: HasCallStack => Text -> Text -> IntO(n+m) The count function returns the number of times the
query string appears in the given Text. An empty query string is
invalid, and will cause an error to be raised.
In (unlikely) bad cases, this function's time complexity degrades towards O(n*m).
zip :: Text -> Text -> [(Char, Char)]O(n) zip takes two Texts and returns a list of
corresponding pairs of bytes. If one input Text is short,
excess elements of the longer Text are discarded. This is
equivalent to a pair of unpack operations.
zipWith :: (Char -> Char -> Char) -> Text -> Text -> TextO(n) zipWith generalises zip by zipping with the function
given as the first argument, instead of a tupling function.
Performs replacement on invalid scalar values.
show :: Show a => a -> TextConvert a value to Text.
copy :: Text -> TextO(n) Make a distinct copy of the given string, sharing no storage with the original string.
As an example, suppose you read a large string, of which you need
only a small portion. If you do not use copy, the entire original
array will be kept alive in memory by the smaller string. Making a
copy "breaks the link" to the original array, allowing it to be
garbage collected if there are no other live references to it.
unpackCString# :: Addr# -> TextO(n) Convert a null-terminated
modified UTF-8
(but with a standard UTF-8 representation of characters from supplementary planes)
string to a Text. Counterpart to unpackCStringUtf8#.
No validation is performed, malformed input can lead to memory access violation.
unpackCStringAscii# :: Addr# -> TextO(n) Convert a null-terminated ASCII string to a Text.
Counterpart to unpackCString#.
No validation is performed, malformed input can lead to memory access violation.
measureOff :: Int -> Text -> IntO(n) If t is long enough to contain n characters, measureOff n t
returns a non-negative number, measuring their size in Word8. Otherwise,
if t is shorter, return a non-positive number, which is a negated total count
of Char available in t. If t is empty or n = 0, return 0.
This function is used to implement take, drop, splitAt and length
and is useful on its own in streaming and parsing libraries.
instance Eq Textinstance Ord Textinstance Read Textinstance Semigroup TextBeware: stimes will crash if the given number does not fit into
an Int.
instance Monoid Textinstance IsString TextPerforms replacement on invalid scalar values:
>>> :set -XOverloadedStrings
>>> "\55555" :: Text
"\65533"
instance Exts.IsList TextPerforms replacement on invalid scalar values:
>>> :set -XOverloadedLists
>>> ['\55555'] :: Text
"\65533"
instance NFData Textinstance Binary Textinstance Data TextThis instance preserves data abstraction at the cost of inefficiency. We omit reflection services for the sake of data abstraction.
This instance was created by copying the updated behavior of
Data.Set.Set and Data.Map.Map. If you
feel a mistake has been made, please feel free to submit
improvements.
The original discussion is archived here: could we get a Data instance for Data.Text.Text?
The followup discussion that changed the behavior of Set
and Map is archived here:
Proposal: Allow gunfold for Data.Map, ...
instance TH.Lift Textinstance PrintfArg TextCommunity contribution. The service has not verified this documentation. The generator reported 2 diagnostics.
Target: Linux on x86-64. Some inferred types and resolved links are not available.
Generator: aihc-haddock-858b1951-web-1
Metadata snapshot: 0b0724abd14577f7a6c8172d62e3e1c0808feb114d4d379402e17f37e3c7801e
Open the dependency plan · Download the documentation model